b29b852281
config/ directory. We split them apart a while ago in the hopes that
it would simplify things, but it didn't really (e.g., because there
were still some ompi/opal .m4 files in the top-level config/
directory, resulting in developer confusion where any given m4 macro
was defined).
So this commit consolidates them back into the top-level directory for
simplicity.
There's still (at least) two changes that would be nice to make:
1. Split any generated .m4 file (e.g., autogen-generated .m4 files)
into a separate directory somewhere so that a top-level -Iconfig/
will only get our explicitly defined macros, not the autogen stuff
(e.g., with libevent2019 needing to get the visibility macro, but
NOT all the autogen-generated inclusion of component configure.m4
files).
1. Change configure to be of the form:
{{{
# ...a small amount of preamble/setup...
OPAL_SETUP
m4_ifdef([project_orte], [ORTE_SETUP])
m4_ifdef([project_ompi], [OMPI_SETUP])
# ...a small amount of finishing stuff...
}}}
I doubt we'll ever get anything as clean as that, but that would be
the goal to shoot for.
This commit was SVN r27704.
58 строки
2.1 KiB
Bash
58 строки
2.1 KiB
Bash
# -*- shell-script -*-
|
|
#
|
|
# Copyright (C) Mellanox Technologies Ltd. 2001-2011. ALL RIGHTS RESERVED.
|
|
# $COPYRIGHT$
|
|
#
|
|
# Additional copyrights may follow
|
|
#
|
|
# $HEADER$
|
|
#
|
|
|
|
# OMPI_CHECK_MXM(prefix, [action-if-found], [action-if-not-found])
|
|
# --------------------------------------------------------
|
|
# check if MXM support can be found. sets prefix_{CPPFLAGS,
|
|
# LDFLAGS, LIBS} as needed and runs action-if-found if there is
|
|
# support, otherwise executes action-if-not-found
|
|
AC_DEFUN([OMPI_CHECK_MXM],[
|
|
AC_ARG_WITH([mxm],
|
|
[AC_HELP_STRING([--with-mxm(=DIR)],
|
|
[Build Mellanox Messaging support])])
|
|
OMPI_CHECK_WITHDIR([mxm], [$with_mxm], [include/mxm/api/mxm_api.h])
|
|
AC_ARG_WITH([mxm-libdir],
|
|
[AC_HELP_STRING([--with-mxm-libdir=DIR],
|
|
[Search for Mellanox Messaging libraries in DIR])])
|
|
OMPI_CHECK_WITHDIR([mxm-libdir], [$with_mxm_libdir], [libmxm.*])
|
|
|
|
ompi_check_mxm_$1_save_CPPFLAGS="$CPPFLAGS"
|
|
ompi_check_mxm_$1_save_LDFLAGS="$LDFLAGS"
|
|
ompi_check_mxm_$1_save_LIBS="$LIBS"
|
|
|
|
AS_IF([test "$with_mxm" != "no"],
|
|
[AS_IF([test ! -z "$with_mxm" -a "$with_mxm" != "yes"],
|
|
[ompi_check_mxm_dir="$with_mxm"])
|
|
AS_IF([test ! -z "$with_mxm_libdir" -a "$with_mxm_libdir" != "yes"],
|
|
[ompi_check_mxm_libdir="$with_mxm_libdir"])
|
|
|
|
OMPI_CHECK_PACKAGE([$1],
|
|
[mxm/api/mxm_api.h],
|
|
[mxm],
|
|
[mxm_cleanup],
|
|
[],
|
|
[$ompi_check_mxm_dir],
|
|
[$ompi_check_mxm_libdir],
|
|
[ompi_check_mxm_happy="yes"],
|
|
[ompi_check_mxm_happy="no"])],
|
|
[ompi_check_mxm_happy="no"])
|
|
|
|
CPPFLAGS="$ompi_check_mxm_$1_save_CPPFLAGS"
|
|
LDFLAGS="$ompi_check_mxm_$1_save_LDFLAGS"
|
|
LIBS="$ompi_check_mxm_$1_save_LIBS"
|
|
|
|
AS_IF([test "$ompi_check_mxm_happy" = "yes"],
|
|
[$2],
|
|
[AS_IF([test ! -z "$with_mxm" -a "$with_mxm" != "no"],
|
|
[AC_MSG_ERROR([MXM support requested but not found. Aborting])])
|
|
$3])
|
|
])
|
|
|