80 строки
1.9 KiB
Bash
80 строки
1.9 KiB
Bash
dnl -*- shell-script -*-
|
|
dnl
|
|
dnl $HEADER$
|
|
dnl
|
|
|
|
define([OMPI_CXX_FIND_EXCEPTION_FLAGS],[
|
|
#
|
|
# Arguments: none
|
|
#
|
|
# Dependencies: none
|
|
#
|
|
# Get the exception handling flags for the C++ compiler. Leaves
|
|
# CXXFLAGS undisturbed.
|
|
# Provides --with-exflags command line argument for configure as well.
|
|
#
|
|
# Sets OMPI_CXX_EXCEPTION_CXXFLAGS and OMPI_CXX_EXCEPTION_LDFLAGS as
|
|
# appropriate.
|
|
# Must call AC_SUBST manually
|
|
#
|
|
|
|
# Command line flags
|
|
|
|
AC_ARG_WITH(exflags,
|
|
AC_HELP_STRING([--with-exflags],
|
|
[Specify flags necessary to enable C++ exceptions]),
|
|
ompi_force_exflags="$withval")
|
|
|
|
ompi_CXXFLAGS_SAVE="$CXXFLAGS"
|
|
AC_MSG_CHECKING([for compiler exception flags])
|
|
|
|
# See which flags to use
|
|
|
|
if test "$ompi_force_exflags" != ""; then
|
|
|
|
# If the user supplied flags, use those
|
|
|
|
ompi_exflags="$ompi_force_exflags"
|
|
elif test "$GXX" = "yes"; then
|
|
|
|
# g++ has changed their flags a few times. Sigh.
|
|
|
|
CXXFLAGS="$CXXFLAGS -fexceptions"
|
|
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_COMPILE_IFELSE(AC_LANG_PROGRAM([[]], [[try { int i = 0; } catch(...) { int j = 2; }]]), ompi_happy=1, ompi_happy=0)
|
|
|
|
if test "$ompi_happy" = "1"; then
|
|
ompi_exflags="-fexceptions";
|
|
else
|
|
CXXFLAGS="$CXXFLAGS_SAVE -fhandle-exceptions"
|
|
AC_COMPILE_IFELSE(AC_LANG_PROGRAM([[]], [[try { int i = 0; } catch(...) { int j = 2; }]]), ompi_happy=1, ompi_happy=0)
|
|
if test "$ompi_happy" = "1"; then
|
|
ompi_exflags="-fhandle-exceptions";
|
|
fi
|
|
fi
|
|
AC_LANG_RESTORE
|
|
elif test "`basename $CXX`" = "KCC"; then
|
|
|
|
# KCC flags
|
|
|
|
ompi_exflags="--exceptions"
|
|
fi
|
|
CXXFLAGS="$ompi_CXXFLAGS_SAVE"
|
|
|
|
# Save the result
|
|
|
|
OMPI_CXX_EXCEPTIONS_CXXFLAGS="$ompi_exflags"
|
|
OMPI_CXX_EXCEPTIONS_LDFLAGS="$ompi_exflags"
|
|
if test "$ompi_exflags" = ""; then
|
|
AC_MSG_RESULT([none necessary])
|
|
else
|
|
AC_MSG_RESULT([$ompi_exflags])
|
|
fi
|
|
|
|
# Clean up
|
|
|
|
unset ompi_force_exflags ompi_CXXFLAGS_SAVE ompi_exflags ompi_happy])dnl
|
|
|