Modify the configure system so that gridengine support is only built in specific conditions:

1. --with-sge, always builds
2. --without-sge, never builds
3. if neither is specified, build if and only if either SGE_ROOT is set or "qrsh" is found in the path

This commit was SVN r16422.

acinclude.m4

@@ -75,6 +75,7 @@ m4_include(config/ompi_check_psm.m4)
 m4_include(config/ompi_check_udapl.m4)
 m4_include(config/ompi_check_package.m4)
 m4_include(config/ompi_check_loadleveler.m4)
+m4_include(config/ompi_check_sge.m4)
 m4_include(config/ompi_check_slurm.m4)
 m4_include(config/ompi_check_tm.m4)
 m4_include(config/ompi_check_xgrid.m4)

config/ompi_check_sge.m4

@@ -0,0 +1,53 @@
+# -*- shell-script -*-
+#
+# Copyright (c) 2004-2005 The Trustees of Indiana University and Indiana
+#                         University Research and Technology
+#                         Corporation.  All rights reserved.
+# Copyright (c) 2004-2005 The University of Tennessee and The University
+#                         of Tennessee Research Foundation.  All rights
+#                         reserved.
+# Copyright (c) 2004-2005 High Performance Computing Center Stuttgart, 
+#                         University of Stuttgart.  All rights reserved.
+# Copyright (c) 2004-2005 The Regents of the University of California.
+#                         All rights reserved.
+# Copyright (c) 2006-2007 Cisco Systems, Inc.  All rights reserved.
+# $COPYRIGHT$
+# 
+# Additional copyrights may follow
+# 
+# $HEADER$
+#
+
+# 1. if --with-sge is given, always build
+# 2. if --without-sge is given, never build
+# 3. if neither is given, build if-and-only-if you find either qrsh in path or
+# sge_root in environment
+
+# OMPI_CHECK_GRIDENGINE(prefix, [action-if-found], [action-if-not-found])
+# --------------------------------------------------------
+AC_DEFUN([OMPI_CHECK_GRIDENGINE],[
+    AC_ARG_WITH([sge],
+                [AC_HELP_STRING([--with-sge],
+                                [Build SGE or Grid Engine support (default: no)])])
+
+    AC_MSG_CHECKING([if user requested SGE build])
+    ompi_gridengine_build=
+    AS_IF([test "$with_sge" = "yes"],
+          [AC_MSG_RESULT([yes])
+           ompi_gridengine_build=yes],
+          [AS_IF([test "$with_sge" = "no"],
+                 [AC_MSG_RESULT([no])],
+                 [AC_MSG_RESULT([not specified; checking environment])
+                  AC_CHECK_PROG([QRSH], [qrsh], [qrsh])
+                  AS_IF([test "$QRSH" != ""],
+                        [ompi_gridengine_build=yes],
+                        [AC_MSG_CHECKING([for SGE_ROOT environment variable])
+                         AS_IF([test "$SGE_ROOT" != ""],
+                               [AC_MSG_RESULT([found])
+                                ompi_gridengine_build=yes],
+                               [AC_MSG_RESULT([not found])])])])])
+
+    AS_IF([test "$ompi_gridengine_build" = "yes"],
+          [$2], 
+          [$3])
+])

orte/mca/pls/gridengine/configure.m4

@@ -22,5 +22,5 @@
 # MCA_pls_sge_CONFIG([action-if-found], [action-if-not-found])
 # -----------------------------------------------------------
 AC_DEFUN([MCA_pls_gridengine_CONFIG],[
-    AC_CHECK_FUNC([fork], [$1], [$2])
+    OMPI_CHECK_GRIDENGINE([pls_gridengine], [$1], [$2])
 ])dnl

orte/mca/ras/gridengine/configure.m4

@@ -22,5 +22,5 @@
 # MCA_ras_sge_CONFIG([action-if-found], [action-if-not-found])
 # -----------------------------------------------------------
 AC_DEFUN([MCA_ras_gridengine_CONFIG],[
-    AC_CHECK_FUNC([fork], [$1], [$2])
+    OMPI_CHECK_GRIDENGINE([ras_gridengine], [$1], [$2])
 ])dnl