Another project that has been brewing for a week or so...

We have repeatedly seen users inadvertantly try to use a C compiler
for $CXX (e.g., using icc instead of icpc in recent versions of the
Intel compiler).  Unfortunately, this would "sorta work", meaning that
configure would complete successfully and the build would fail much
later in the process (when $CXX was used to try to link a C++
compiler).  This was further compounded by the fact that many C
compilers will switch into "C++ mode" when they compile files that end
in .cc -- meaning that they'll *compile* C++ codes properly, but they
won't *link* properly.  Hence, users would get all the way down to
compiling the C++ MPI bindings or ompi_info (i.e., very late in the
build process) before the problem became evident.

We already have a test in configure that tries to compile, link, and
run a sample C++ program.  This helped ensure that $CXX was a valid
compiler, but it did not catch if the user accidentally supplied a C
compiler instead of a C++ compiler because the test program was simply
"return 0".  This commit updates the test program to use some
C++-specific constructs (std::string) so that if the user supplies a C
compiler in $CXX, the program may *compile*, but it will definitely
fail to *link*.

Hence, the process will fail early in configure (with a descriptive
message about how the compiler failed to work properly) rather than
late in the build.

This commit was SVN r10829.

config/ompi_check_compiler_works.m4

@@ -10,24 +10,25 @@ dnl
 dnl $HEADER$
 dnl
 
-# OMPI_CHECK_COMPILER_WORKS(language, language_exit,
+# OMPI_CHECK_COMPILER_WORKS(language, headers, body,
 #            [action-if-found], [action-if-not-found])
 # ----------------------------------------------------
-# Try to compile and run a simple "exit(0)" application in
-# 'language'.  A warning is always printed if the application
-# fails to run.  Action-if-found is evaluated if the application
-# runs successfully (or compiles if cross-compiling), and
-# action-if-not-found is evaluated if the application fails to
-# run.
+# Try to compile and run a simple application in 'language'.  A
+# warning is always printed if the application fails to run.
+# Action-if-found is evaluated if the application runs successfully
+# (or compiles if cross-compiling), and action-if-not-found is
+# evaluated if the application fails to run.
 #
-# language-exit should be how to exit cleanly in 'language'.
-# You probably want exit(0) for C/C++ and empty for Fortran.
+# headers are any headers needed to compile the body (e.g., #include
+# statements), and body is the program to compile.  It should include
+# a clean exit from the application (e.g., "return 0" in C/C++, empty in
+# fortran).
 AC_DEFUN([OMPI_CHECK_COMPILER_WORKS],
 [   AS_VAR_PUSHDEF([lang_var], [ompi_cv_$1_works])
 
     AC_CACHE_CHECK([if $1 compiler works], lang_var,
         [AC_LANG_PUSH($1)
-         AC_RUN_IFELSE([AC_LANG_PROGRAM([], [$2])],
+         AC_RUN_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
                        [AS_VAR_SET(lang_var, ["yes"])],
                        [AS_VAR_SET(lang_var, ["no"])],
                        [AS_VAR_SET(lang_var, ["cross compiling"])])
@@ -44,7 +45,7 @@ AC_DEFUN([OMPI_CHECK_COMPILER_WORKS],
 * available in the config.log file in this directory.
 **********************************************************************
 EOF
-           $4], [$3])
+           $5], [$4])
 
     AS_VAR_POPDEF([lang_var])dnl
 ])

config/ompi_setup_cxx.m4

@@ -217,9 +217,20 @@ AC_DEFUN([_OMPI_PROG_CXX],[
     OMPI_CXX_ABSOLUTE="`which $CXX`"
     AC_SUBST(OMPI_CXX_ABSOLUTE)
 
-    # make sure the compiler actually works, if not cross-compiling.
-    # Don't just use the AC macro so that we can have a pretty
-    # message.
-    OMPI_CHECK_COMPILER_WORKS([C++], [return 0], [], 
+    # Make sure that the C++ compiler both works and is actually a C++
+    # compiler (if not cross-compiling).  Don't just use the AC macro
+    # so that we can have a pretty message.  Do something here that
+    # should force the linking of C++-specific things (e.g., STL
+    # strings) so that we can force a hard check of compiling,
+    # linking, and running a C++ application Note that some C
+    # compilers, such as at least some versions of the GNU and Intel
+    # compilers, will detect that the file extension is ".cc" and
+    # therefore switch into a pseudo-C++ personality which works for
+    # *compiling*, but does not work for *linking*.  So in this test,
+    # we want to cover the entire spectrum (compiling, linking,
+    # running).
+
+    OMPI_CHECK_COMPILER_WORKS([C++], [#include <string>], 
+           [std::string foo = "Hello, world"; return 0], [], 
            [AC_MSG_ERROR([Could not run a simple C++ program.  Aborting.])])
 ])

config/ompi_setup_f77.m4

@@ -73,7 +73,7 @@ fi
 # Don't just use the AC macro so that we can have a pretty
 # message.
 AS_IF([test $OMPI_WANT_F77_BINDINGS -eq 1],
-       [OMPI_CHECK_COMPILER_WORKS([Fortran 77], [], [], 
+       [OMPI_CHECK_COMPILER_WORKS([Fortran 77], [], [], [], 
            [AC_MSG_ERROR([Could not run a simple Fortran 77 program.  Aborting.])])])
 
 AC_DEFINE_UNQUOTED(OMPI_WANT_F77_BINDINGS, $OMPI_WANT_F77_BINDINGS,

config/ompi_setup_f90.m4

@@ -95,7 +95,7 @@ fi
 # Don't just use the AC macro so that we can have a pretty
 # message.
 AS_IF([test $OMPI_WANT_F90_BINDINGS -eq 1],
-       [OMPI_CHECK_COMPILER_WORKS([Fortran], [], [], 
+       [OMPI_CHECK_COMPILER_WORKS([Fortran], [], [], [],
            [AC_MSG_ERROR([Could not run a simple Fortran program.  Aborting.])])])
 
 # check to see if the F77 and F90 compilers are compatible