* acinclude.m4 (AC_GET_FS_INFO): Make it work again - the last commit broke

it.
* m4/onceonly.m4: New file.

ChangeLog

@@ -1,3 +1,9 @@
+2006-04-18  Pavel Tsekov  <ptsekov@gmx.net>
+
+	* acinclude.m4 (AC_GET_FS_INFO): Make it work again - the last
+	commit broke it.
+	* m4/onceonly.m4: New file.
+
 2006-04-13  Anton Monroe  <akm@meer.net>
 
 	* doc/mc.1.in: Function key documentation update.

acinclude.m4

@@ -275,25 +275,14 @@ dnl To get information about the disk, mount points, etc.
 dnl
 
 AC_DEFUN([AC_GET_FS_INFO], [
-    AC_CHECK_HEADERS(fcntl.h sys/dustat.h sys/param.h sys/statfs.h sys/fstyp.h)
-    AC_CHECK_HEADERS(mnttab.h mntent.h utime.h sys/statvfs.h sys/vfs.h)
-    AC_CHECK_HEADERS(sys/filsys.h sys/fs_types.h)
-    AC_CHECK_HEADERS(sys/mount.h, , , [
-#include <sys/param.h>
-#include <sys/stat.h>
-				      ])
-    AC_CHECK_FUNCS(getmntinfo)
+    AC_CHECK_HEADERS([fcntl.h utime.h])
 
-    dnl Include ls-mntd-fs.m4 from GNU coreutils-5.94 (serial 20).
-    dnl Its job is to detect a method to get list of mounted filesystems.
-
-    m4_include([m4/ls-mntd-fs.m4])
-
-    dnl Include fsusage.m4 from GNU coreutils-5.94 (serial 16).
-    dnl Its job is to detect a method to get file system information.
-
-    m4_include([m4/fsusage.m4])
+    gl_LIST_MOUNTED_FILE_SYSTEMS([
+	AC_DEFINE(HAVE_INFOMOUNT_LIST, 1,
+	    [Define if the list of mounted filesystems can be determined])],
+	[AC_MSG_WARN([could not determine how to read list of mounted fs])])
 
+    gl_FSUSAGE
 ])
 
 

m4/onceonly.m4

@@ -0,0 +1,61 @@
+# onceonly.m4 serial 3 (gettext-0.12)
+dnl Copyright (C) 2002, 2003 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This file defines some "once only" variants of standard autoconf macros.
+dnl   AC_CHECK_HEADERS_ONCE         like  AC_CHECK_HEADERS
+dnl   AC_CHECK_FUNCS_ONCE           like  AC_CHECK_FUNCS
+dnl   AC_CHECK_DECLS_ONCE           like  AC_CHECK_DECLS
+dnl   AC_REQUIRE([AC_HEADER_STDC])  like  AC_HEADER_STDC
+dnl The advantage is that the check for each of the headers/functions/decls
+dnl will be put only once into the 'configure' file. It keeps the size of
+dnl the 'configure' file down, and avoids redundant output when 'configure'
+dnl is run.
+dnl The drawback is that the checks cannot be conditionalized. If you write
+dnl   if some_condition; then gl_CHECK_HEADERS(stdlib.h); fi
+dnl inside an AC_DEFUNed function, the gl_CHECK_HEADERS macro call expands to
+dnl empty, and the check will be inserted before the body of the AC_DEFUNed
+dnl function.
+
+dnl Autoconf version 2.57 or newer is recommended.
+AC_PREREQ(2.54)
+
+# AC_CHECK_HEADERS_ONCE(HEADER1 HEADER2 ...) is a once-only variant of
+# AC_CHECK_HEADERS(HEADER1 HEADER2 ...).
+AC_DEFUN([AC_CHECK_HEADERS_ONCE], [
+  :
+  AC_FOREACH([gl_HEADER_NAME], [$1], [
+    AC_DEFUN([gl_CHECK_HEADER_]m4_quote(translit(m4_defn([gl_HEADER_NAME]),
+                                                 [-./], [___])), [
+      AC_CHECK_HEADERS(gl_HEADER_NAME)
+    ])
+    AC_REQUIRE([gl_CHECK_HEADER_]m4_quote(translit(gl_HEADER_NAME,
+                                                   [-./], [___])))
+  ])
+])
+
+# AC_CHECK_FUNCS_ONCE(FUNC1 FUNC2 ...) is a once-only variant of
+# AC_CHECK_FUNCS(FUNC1 FUNC2 ...).
+AC_DEFUN([AC_CHECK_FUNCS_ONCE], [
+  :
+  AC_FOREACH([gl_FUNC_NAME], [$1], [
+    AC_DEFUN([gl_CHECK_FUNC_]m4_defn([gl_FUNC_NAME]), [
+      AC_CHECK_FUNCS(m4_defn([gl_FUNC_NAME]))
+    ])
+    AC_REQUIRE([gl_CHECK_FUNC_]m4_defn([gl_FUNC_NAME]))
+  ])
+])
+
+# AC_CHECK_DECLS_ONCE(DECL1 DECL2 ...) is a once-only variant of
+# AC_CHECK_DECLS(DECL1, DECL2, ...).
+AC_DEFUN([AC_CHECK_DECLS_ONCE], [
+  :
+  AC_FOREACH([gl_DECL_NAME], [$1], [
+    AC_DEFUN([gl_CHECK_DECL_]m4_defn([gl_DECL_NAME]), [
+      AC_CHECK_DECLS(m4_defn([gl_DECL_NAME]))
+    ])
+    AC_REQUIRE([gl_CHECK_DECL_]m4_defn([gl_DECL_NAME]))
+  ])
+])